79 lines
1.9 KiB
QML
79 lines
1.9 KiB
QML
import QtQuick
|
|
import Quickshell
|
|
import Quickshell.Io
|
|
import Quickshell.Services.UPower
|
|
import "BatteryModel.js" as BatteryModel
|
|
|
|
Item {
|
|
id: root
|
|
|
|
property var shell: null
|
|
property string blobPath: Quickshell.env("BLOB_PATH")
|
|
|
|
readonly property int batteryThreshold: 10
|
|
property string pendingPowerSource: ""
|
|
|
|
PersistentProperties {
|
|
id: persisted
|
|
reloadableId: "blob-battery"
|
|
property bool notifiedLowBattery: false
|
|
}
|
|
|
|
function batteryPercentage() {
|
|
return BatteryModel.batteryPercentage(UPower.displayDevice)
|
|
}
|
|
|
|
function isDischarging() {
|
|
return BatteryModel.isDischarging(UPower.displayDevice, UPower.onBattery, UPowerDeviceState.Discharging)
|
|
}
|
|
|
|
function checkBattery() {
|
|
var state = BatteryModel.shouldWarnLowBattery(UPower.displayDevice, UPower.onBattery, UPowerDeviceState.Discharging, batteryThreshold, persisted.notifiedLowBattery)
|
|
persisted.notifiedLowBattery = state.notifiedLowBattery
|
|
if (state.notify) sendLowBatteryWarning(state.level)
|
|
}
|
|
|
|
function sendLowBatteryWarning(level) {
|
|
if (warningProcess.running) return
|
|
warningProcess.command = [
|
|
"blob-battery-low",
|
|
String(level)
|
|
]
|
|
warningProcess.running = true
|
|
}
|
|
|
|
function applyPowerProfile() {
|
|
pendingPowerSource = UPower.onBattery ? "battery" : "ac"
|
|
if (!powerProfileProcess.running) runPendingPowerProfile()
|
|
}
|
|
|
|
function runPendingPowerProfile() {
|
|
powerProfileProcess.command = ["blob-power-set", pendingPowerSource]
|
|
pendingPowerSource = ""
|
|
powerProfileProcess.running = true
|
|
}
|
|
|
|
Process { id: warningProcess }
|
|
|
|
Process {
|
|
id: powerProfileProcess
|
|
onExited: if (root.pendingPowerSource !== "") root.runPendingPowerProfile()
|
|
}
|
|
|
|
Timer {
|
|
interval: 30000
|
|
running: true
|
|
repeat: true
|
|
triggeredOnStart: true
|
|
onTriggered: root.checkBattery()
|
|
}
|
|
|
|
Connections {
|
|
target: UPower
|
|
function onOnBatteryChanged() {
|
|
root.checkBattery()
|
|
root.applyPowerProfile()
|
|
}
|
|
}
|
|
}
|